1# Copyright © 2017-2018 Intel Corporation
2
3# Permission is hereby granted, free of charge, to any person obtaining a copy
4# of this software and associated documentation files (the "Software"), to deal
5# in the Software without restriction, including without limitation the rights
6# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
7# copies of the Software, and to permit persons to whom the Software is
8# furnished to do so, subject to the following conditions:
9
10# The above copyright notice and this permission notice shall be included in
11# all copies or substantial portions of the Software.
12
13# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
14# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
15# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
16# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
17# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
18# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
19# SOFTWARE.
20
21project(
22  'libdrm',
23  ['c'],
24  version : '2.4.91',
25  license : 'MIT',
26  meson_version : '>= 0.43',
27  default_options : ['buildtype=debugoptimized', 'c_std=gnu99'],
28)
29
30pkg = import('pkgconfig')
31
32config = configuration_data()
33
34config.set10('UDEV', get_option('udev'))
35with_freedreno_kgsl = get_option('freedreno-kgsl')
36with_install_tests = get_option('install-test-programs')
37
38if ['freebsd', 'dragonfly', 'netbsd'].contains(host_machine.system())
39  dep_pthread_stubs = dependency('pthread-stubs', version : '>= 0.4')
40else
41  dep_pthread_stubs = []
42endif
43dep_threads = dependency('threads')
44
45cc = meson.get_compiler('c')
46
47# Check for atomics
48intel_atomics = false
49lib_atomics = false
50
51dep_atomic_ops = dependency('atomic_ops', required : false)
52if cc.compiles('''
53    int atomic_add(int *i) { return __sync_add_and_fetch (i, 1); }
54    int atomic_cmpxchg(int *i, int j, int k) { return __sync_val_compare_and_swap (i, j, k); }
55    ''',
56    name : 'Intel Atomics')
57  intel_atomics = true
58  with_atomics = true
59  dep_atomic_ops = []
60elif dep_atomic_ops.found()
61  lib_atomics = true
62  with_atomics = true
63elif cc.has_function('atomic_cas_uint')
64  with_atomics = true
65else
66  with_atomics = false
67endif
68
69config.set10('HAVE_LIBDRM_ATOMIC_PRIMITIVES', intel_atomics)
70config.set10('HAVE_LIB_ATOMIC_OPS', lib_atomics)
71
72with_intel = false
73_intel = get_option('intel')
74if _intel != 'false'
75  if _intel == 'true' and not with_atomics
76    error('libdrm_intel requires atomics.')
77  else
78    with_intel = _intel == 'true' or host_machine.cpu_family().startswith('x86')
79  endif
80endif
81
82with_radeon = false
83_radeon = get_option('radeon')
84if _radeon != 'false'
85  if _radeon == 'true' and not with_atomics
86    error('libdrm_radeon requires atomics.')
87  endif
88  with_radeon = true
89endif
90
91with_amdgpu = false
92_amdgpu = get_option('amdgpu')
93if _amdgpu != 'false'
94  if _amdgpu == 'true' and not with_atomics
95    error('libdrm_amdgpu requires atomics.')
96  endif
97  with_amdgpu = true
98endif
99
100with_nouveau = false
101_nouveau = get_option('nouveau')
102if _nouveau != 'false'
103  if _nouveau == 'true' and not with_atomics
104    error('libdrm_nouveau requires atomics.')
105  endif
106  with_nouveau = true
107endif
108
109with_vmwgfx = false
110_vmwgfx = get_option('vmwgfx')
111if _vmwgfx != 'false'
112  with_vmwgfx = true
113endif
114
115with_omap = false
116_omap = get_option('omap')
117if _omap == 'true'
118  if not with_atomics
119    error('libdrm_omap requires atomics.')
120  endif
121  with_omap = true
122endif
123
124with_freedreno = false
125_freedreno = get_option('freedreno')
126if _freedreno != 'false'
127  if _freedreno == 'true' and not with_atomics
128    error('libdrm_freedreno requires atomics.')
129  else
130    with_freedreno = _freedreno == 'true' or ['arm', 'aarch64'].contains(host_machine.cpu_family())
131  endif
132endif
133
134with_tegra = false
135_tegra = get_option('tegra')
136if _tegra == 'true'
137  if not with_atomics
138    error('libdrm_tegra requires atomics.')
139  endif
140  with_tegra = true
141endif
142
143with_etnaviv = false
144_etnaviv = get_option('etnaviv')
145if _etnaviv == 'true'
146  if not with_atomics
147    error('libdrm_etnaviv requires atomics.')
148  endif
149  with_etnaviv = true
150endif
151
152with_exynos = get_option('exynos') == 'true'
153
154with_vc4 = false
155_vc4 = get_option('vc4')
156if _vc4 != 'false'
157  with_vc4 = _vc4 == 'true' or ['arm', 'aarch64'].contains(host_machine.cpu_family())
158endif
159
160# XXX: Aparently only freebsd and dragonfly bsd actually need this (and
161# gnu/kfreebsd), not openbsd and netbsd
162with_libkms = false
163_libkms = get_option('libkms')
164if _libkms != 'false'
165  with_libkms = _libkms == 'true' or ['linux', 'freebsd', 'dragonfly'].contains(host_machine.system())
166endif
167
168# Among others FreeBSD does not have a separate dl library.
169if not cc.has_function('dlsym')
170  dep_dl = cc.find_library('dl', required : with_nouveau)
171else
172  dep_dl = []
173endif
174# clock_gettime might require -rt, or it might not. find out
175if not cc.has_function('clock_gettime', prefix : '#define _GNU_SOURCE\n#include <time.h>')
176  # XXX: untested
177  dep_rt = cc.find_library('rt')
178else
179  dep_rt = []
180endif
181dep_m = cc.find_library('m', required : false)
182foreach header : ['sys/sysctl.h', 'sys/select.h', 'alloca.h']
183  config.set('HAVE_' + header.underscorify().to_upper(),
184    cc.compiles('#include <@0@>'.format(header), name : '@0@ works'.format(header)))
185endforeach
186if cc.has_header_symbol('sys/sysmacros.h', 'major')
187  config.set10('MAJOR_IN_SYSMACROS', true)
188elif cc.has_header_symbol('sys/mkdev.h', 'major')
189  config.set10('MAJOR_IN_MKDEV', true)
190endif
191config.set10('HAVE_OPEN_MEMSTREAM', cc.has_function('open_memstream'))
192
193warn_c_args = []
194foreach a : ['-Wall', '-Wextra', '-Wsign-compare', '-Werror=undef',
195             '-Werror-implicit-function-declaration', '-Wpointer-arith',
196             '-Wwrite-strings', '-Wstrict-prototypes', '-Wmissing-prototypes',
197             '-Wmissing-declarations', '-Wnested-externs', '-Wpacked',
198             '-Wswitch-enum', '-Wmissing-format-attribute',
199             '-Wstrict-aliasing=2', '-Winit-self', '-Winline', '-Wshadow',
200             '-Wdeclaration-after-statement', '-Wold-style-definition']
201  if cc.has_argument(a)
202    warn_c_args += a
203  endif
204endforeach
205# GCC will never error for -Wno-*, so check for -W* then add -Wno-* to the list
206# of options
207foreach a : ['unused-parameter', 'attributes', 'long-long',
208             'missing-field-initializers']
209  if cc.has_argument('-W@0@'.format(a))
210    warn_c_args += '-Wno-@0@'.format(a)
211  endif
212endforeach
213
214
215dep_pciaccess = dependency('pciaccess', version : '>= 0.10', required : with_intel)
216dep_cunit = dependency('cunit', version : '>= 2.1', required : false)
217_cairo_tests = get_option('cairo-tests')
218if _cairo_tests != 'false'
219  dep_cairo = dependency('cairo', required : _cairo_tests == 'true')
220  with_cairo_tests = dep_cairo.found()
221else
222  dep_cairo = []
223  with_cairo_tests = false
224endif
225_valgrind = get_option('valgrind')
226if _valgrind != 'false'
227  dep_valgrind = dependency('valgrind', required : _valgrind == 'true')
228  with_valgrind = dep_valgrind.found()
229else
230  dep_valgrind = []
231  with_valgrind = false
232endif
233
234with_man_pages = get_option('man-pages')
235prog_xslt = find_program('xsltproc', required : with_man_pages == 'true')
236prog_sed = find_program('sed', required : with_man_pages == 'true')
237manpage_style = 'http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl'
238if prog_xslt.found()
239  if run_command(prog_xslt, '--nonet', manpage_style).returncode() != 0
240    if with_man_pages == 'true'
241      error('Manpage style sheet cannot be found')
242    endif
243    with_man_pages = 'false'
244  endif
245endif
246with_man_pages = with_man_pages != 'false' and prog_xslt.found() and prog_sed.found()
247
248# Used for tets
249prog_bash = find_program('bash')
250
251config.set10('HAVE_VISIBILITY',
252  cc.compiles('''int foo_hidden(void) __attribute__((visibility(("hidden"))));''',
253              name : 'compiler supports __attribute__(("hidden"))'))
254
255foreach t : [
256             [with_exynos, 'EXYNOS'],
257             [with_freedreno_kgsl, 'FREEDRENO_KGSL'],
258             [with_intel, 'INTEL'],
259             [with_nouveau, 'NOUVEAU'],
260             [with_radeon, 'RADEON'],
261             [with_vc4, 'VC4'],
262             [with_vmwgfx, 'VMWGFX'],
263             [with_cairo_tests, 'CAIRO'],
264             [with_valgrind, 'VALGRIND'],
265            ]
266  config.set10('HAVE_@0@'.format(t[1]), t[0])
267endforeach
268if with_freedreno_kgsl and not with_freedreno
269  error('cannot enable freedreno-kgsl without freedreno support')
270endif
271config.set10('_GNU_SOURCE', true)
272config_file = configure_file(
273  configuration : config,
274  output : 'config.h',
275)
276add_project_arguments('-include', 'config.h', language : 'c')
277
278inc_root = include_directories('.')
279inc_drm = include_directories('include/drm')
280
281libdrm = shared_library(
282  'drm',
283  [files(
284     'xf86drm.c', 'xf86drmHash.c', 'xf86drmRandom.c', 'xf86drmSL.c',
285     'xf86drmMode.c'
286   ),
287   config_file,
288  ],
289  c_args : warn_c_args,
290  dependencies : [dep_valgrind, dep_rt, dep_m],
291  include_directories : inc_drm,
292  version : '2.4.0',
293  install : true,
294)
295
296ext_libdrm = declare_dependency(
297  link_with : libdrm,
298  include_directories : [inc_root, inc_drm],
299)
300
301install_headers('libsync.h', 'xf86drm.h', 'xf86drmMode.h')
302install_headers(
303  'include/drm/drm.h', 'include/drm/drm_fourcc.h', 'include/drm/drm_mode.h',
304  'include/drm/drm_sarea.h', 'include/drm/i915_drm.h',
305  'include/drm/mach64_drm.h', 'include/drm/mga_drm.h',
306  'include/drm/nouveau_drm.h', 'include/drm/qxl_drm.h',
307  'include/drm/r128_drm.h', 'include/drm/radeon_drm.h',
308  'include/drm/amdgpu_drm.h', 'include/drm/savage_drm.h',
309  'include/drm/sis_drm.h', 'include/drm/tegra_drm.h', 'include/drm/vc4_drm.h',
310  'include/drm/via_drm.h', 'include/drm/virtgpu_drm.h',
311  subdir : 'libdrm',
312)
313if with_vmwgfx
314  install_headers('include/drm/vmwgfx_drm.h', subdir : 'libdrm')
315endif
316
317pkg.generate(
318  name : 'libdrm',
319  libraries : libdrm,
320  subdirs : ['.', 'libdrm'],
321  version : meson.project_version(),
322  description : 'Userspace interface to kernel DRM services',
323)
324
325env_test = environment()
326env_test.set('NM', find_program('nm').path())
327
328if with_libkms
329  subdir('libkms')
330endif
331if with_intel
332  subdir('intel')
333endif
334if with_nouveau
335  subdir('nouveau')
336endif
337if with_radeon
338  subdir('radeon')
339endif
340if with_amdgpu
341  subdir('amdgpu')
342endif
343if with_omap
344  subdir('omap')
345endif
346if with_exynos
347  subdir('exynos')
348endif
349if with_freedreno
350  subdir('freedreno')
351endif
352if with_tegra
353  subdir('tegra')
354endif
355if with_vc4
356  subdir('vc4')
357endif
358if with_etnaviv
359  subdir('etnaviv')
360endif
361if with_man_pages
362  subdir('man')
363endif
364subdir('data')
365subdir('tests')
366
367message('')
368message('@0@ will be compiled with:'.format(meson.project_name()))
369message('')
370message('  libkms         @0@'.format(with_libkms))
371message('  Intel API      @0@'.format(with_intel))
372message('  vmwgfx API     @0@'.format(with_vmwgfx))
373message('  Radeon API     @0@'.format(with_radeon))
374message('  AMDGPU API     @0@'.format(with_amdgpu))
375message('  Nouveau API    @0@'.format(with_nouveau))
376message('  OMAP API       @0@'.format(with_omap))
377message('  EXYNOS API     @0@'.format(with_exynos))
378message('  Freedreno API  @0@ (kgsl: @1@)'.format(with_freedreno, with_freedreno_kgsl))
379message('  Tegra API      @0@'.format(with_tegra))
380message('  VC4 API        @0@'.format(with_vc4))
381message('  Etnaviv API    @0@'.format(with_etnaviv))
382message('')
383