1# ~~~
2# Copyright (c) 2014-2019 Valve Corporation
3# Copyright (c) 2014-2019 LunarG, Inc.
4#
5# Licensed under the Apache License, Version 2.0 (the "License");
6# you may not use this file except in compliance with the License.
7# You may obtain a copy of the License at
8#
9#     http://www.apache.org/licenses/LICENSE-2.0
10#
11# Unless required by applicable law or agreed to in writing, software
12# distributed under the License is distributed on an "AS IS" BASIS,
13# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
14# See the License for the specific language governing permissions and
15# limitations under the License.
16# ~~~
17
18set(GTEST_LOCATION ${CMAKE_CURRENT_SOURCE_DIR}/../external/googletest)
19
20# Needed to make structure definitions match with glslang libraries
21add_definitions(-DNV_EXTENSIONS -DAMD_EXTENSIONS)
22
23if(WIN32)
24    add_definitions(-DVK_USE_PLATFORM_WIN32_KHR -DWIN32_LEAN_AND_MEAN)
25    # Workaround for TR1 deprecation in Visual Studio 15.5 until Google Test is updated
26    add_definitions(-D_SILENCE_TR1_NAMESPACE_DEPRECATION_WARNING)
27elseif(ANDROID)
28    add_definitions(-DVK_USE_PLATFORM_ANDROID_KHR)
29elseif(APPLE)
30    add_definitions(-DVK_USE_PLATFORM_MACOS_MVK)
31elseif(UNIX AND NOT APPLE) # i.e. Linux
32    if(BUILD_WSI_XCB_SUPPORT)
33        add_definitions(-DVK_USE_PLATFORM_XCB_KHR)
34    endif()
35
36    if(BUILD_WSI_XLIB_SUPPORT)
37        add_definitions(-DVK_USE_PLATFORM_XLIB_KHR)
38    endif()
39
40    if(BUILD_WSI_WAYLAND_SUPPORT)
41        add_definitions(-DVK_USE_PLATFORM_WAYLAND_KHR)
42    endif()
43else()
44    message(FATAL_ERROR "Unsupported Platform!")
45endif()
46
47if(WIN32)
48    file(COPY vk_layer_validation_tests.vcxproj.user DESTINATION ${CMAKE_BINARY_DIR}/tests)
49endif()
50
51if(WIN32)
52    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_CRT_SECURE_NO_WARNINGS -D_USE_MATH_DEFINES")
53
54    # If MSVC, disable some signed/unsigned mismatch warnings.
55    if(MSVC)
56        set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4267")
57    endif()
58
59else()
60    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
61endif()
62
63set(LIBGLM_INCLUDE_DIR ${PROJECT_SOURCE_DIR}/libs)
64
65set(COMMON_CPP vkrenderframework.cpp vktestbinding.cpp vktestframework.cpp test_environment.cpp)
66
67if(NOT WIN32)
68    # extra setup for out-of-tree builds
69    if(NOT (CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR))
70        add_custom_target(VulkanVL_binary_dir_symlinks ALL COMMAND ln -sf ${CMAKE_CURRENT_SOURCE_DIR}/run_all_tests.sh VERBATIM)
71    endif()
72else()
73    if(NOT (CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR))
74        file(TO_NATIVE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/_run_all_tests.ps1 RUN_ALL)
75        add_custom_target(VulkanVL_binary_dir_symlinks ALL
76                          COMMAND ${CMAKE_COMMAND} -E copy_if_different ${RUN_ALL} run_all_tests.ps1
77                          VERBATIM)
78        set_target_properties(VulkanVL_binary_dir_symlinks PROPERTIES FOLDER ${LAYERS_HELPER_FOLDER})
79    endif()
80endif()
81
82# ~~~
83# The vulkan loader search is:
84#     Existing vulkan target already present in the build
85#     User-supplied setting of CMAKE_PREFIX_PATH
86#     VULKAN_LOADER_INSTALL_DIR defined via cmake option
87#     VULKAN_LOADER_INSTALL_DIR defined via environment variable
88#     Default findVulkan operation if the VULKAN_SDK environment variable is defined
89# ~~~
90set(VULKAN_LOADER_INSTALL_DIR "LOADER-NOTFOUND" CACHE PATH "Absolute path to a Vulkan-Loader install directory")
91
92if(NOT TARGET vulkan)
93    if(VULKAN_LOADER_INSTALL_DIR)
94        message(STATUS "VULKAN_LOADER_INSTALL_DIR specified, using find_package to locate Vulkan")
95    elseif(ENV{VULKAN_LOADER_INSTALL_DIR})
96        message(STATUS "VULKAN_LOADER_INSTALL_DIR environment variable specified, using find_package to locate Vulkan")
97    endif()
98    set(
99        CMAKE_PREFIX_PATH
100        ${CMAKE_PREFIX_PATH};${VULKAN_LOADER_INSTALL_DIR};${VULKAN_HEADERS_INSTALL_DIR};$ENV{VULKAN_LOADER_INSTALL_DIR};$ENV{VULKAN_HEADERS_INSTALL_DIR}
101        )
102    find_package(Vulkan)
103endif()
104
105set_source_files_properties(${PROJECT_BINARY_DIR}/vk_safe_struct.cpp PROPERTIES GENERATED TRUE)
106add_executable(vk_layer_validation_tests
107               layer_validation_tests.cpp
108               ../layers/vk_format_utils.cpp
109               ../layers/convert_to_renderpass2.cpp
110               ${PROJECT_BINARY_DIR}/vk_safe_struct.cpp
111               ${COMMON_CPP})
112add_dependencies(vk_layer_validation_tests Vulkan::Vulkan)
113if(NOT GTEST_IS_STATIC_LIB)
114    set_target_properties(vk_layer_validation_tests PROPERTIES COMPILE_DEFINITIONS "GTEST_LINKED_AS_SHARED_LIBRARY=1")
115endif()
116target_include_directories(vk_layer_validation_tests
117                           PUBLIC ${CMAKE_CURRENT_SOURCE_DIR}
118                                  ${GTEST_LOCATION}/googletest/include
119                                  ${PROJECT_SOURCE_DIR}/layers
120                                  ${GLSLANG_SPIRV_INCLUDE_DIR}
121                                  ${SPIRV_TOOLS_INCLUDE_DIR}
122                                  ${CMAKE_CURRENT_BINARY_DIR}
123                                  ${CMAKE_BINARY_DIR}
124                                  ${PROJECT_BINARY_DIR}
125                                  ${PROJECT_BINARY_DIR}/layers)
126add_dependencies(vk_layer_validation_tests
127                 VkLayer_utils
128                 VkLayer_core_validation-json
129                 VkLayer_device_profile_api-json
130                 VkLayer_object_lifetimes-json
131                 VkLayer_stateless_validation-json
132                 VkLayer_standard_validation-json
133                 VkLayer_thread_safety-json
134                 VkLayer_unique_objects-json)
135
136# Specify target_link_libraries
137if(WIN32)
138    target_link_libraries(vk_layer_validation_tests
139                          PRIVATE Vulkan::Vulkan
140                                  gtest
141                                  gtest_main
142                                  ${GLSLANG_LIBRARIES})
143else()
144    target_compile_options(vk_layer_validation_tests PRIVATE "-Wno-sign-compare")
145    if(BUILD_WSI_XCB_SUPPORT OR BUILD_WSI_XLIB_SUPPORT)
146        target_link_libraries(vk_layer_validation_tests
147                              PRIVATE Vulkan::Vulkan
148                                      ${XCB_LIBRARIES}
149                                      ${X11_LIBRARIES}
150                                      gtest
151                                      gtest_main
152                                      ${GLSLANG_LIBRARIES})
153    else()
154        target_link_libraries(vk_layer_validation_tests
155                              PRIVATE Vulkan::Vulkan
156                                      gtest
157                                      gtest_main
158                                      ${GLSLANG_LIBRARIES})
159    endif()
160endif()
161
162if(WIN32)
163    # For Windows, copy necessary gtest DLLs to the right spot for the vk_layer_tests...
164    if(NOT GTEST_IS_STATIC_LIB)
165        file(TO_NATIVE_PATH ${PROJECT_BINARY_DIR}/external/googletest/googletest/$<CONFIG>/*.dll SRC_GTEST_DLLS)
166        file(TO_NATIVE_PATH ${CMAKE_CURRENT_BINARY_DIR}/$<CONFIG> DST_GTEST_DLLS)
167        add_custom_command(TARGET vk_layer_validation_tests POST_BUILD
168                           COMMAND xcopy /Y /I ${SRC_GTEST_DLLS} ${DST_GTEST_DLLS})
169    endif()
170    # Copy the loader shared lib (if supplied) to the test application directory so the test app finds it.
171    if(VULKAN_LOADER_INSTALL_DIR)
172        add_custom_command(TARGET vk_layer_validation_tests POST_BUILD
173                           COMMAND ${CMAKE_COMMAND} -E copy ${VULKAN_LOADER_INSTALL_DIR}/bin/vulkan-1.dll
174                                   $<TARGET_FILE_DIR:vk_layer_validation_tests>)
175    endif()
176endif()
177
178if(INSTALL_TESTS)
179    install(TARGETS vk_layer_validation_tests DESTINATION ${CMAKE_INSTALL_BINDIR})
180endif()
181
182add_subdirectory(layers)
183