1// RUN: mlir-opt -convert-gpu-to-spirv %s -o - | FileCheck %s
2
3module attributes {
4  gpu.container_module,
5  spv.target_env = #spv.target_env<
6    #spv.vce<v1.0, [Shader], [SPV_KHR_storage_buffer_storage_class]>, {}>
7} {
8  func @loop(%arg0 : memref<10xf32>, %arg1 : memref<10xf32>) {
9    %c0 = constant 1 : index
10    gpu.launch_func @kernels::@loop_kernel
11        blocks in (%c0, %c0, %c0) threads in (%c0, %c0, %c0)
12        args(%arg0 : memref<10xf32>, %arg1 : memref<10xf32>)
13    return
14  }
15
16  gpu.module @kernels {
17    gpu.func @loop_kernel(%arg2 : memref<10xf32>, %arg3 : memref<10xf32>) kernel
18    attributes {spv.entry_point_abi = {local_size = dense<[16, 1, 1]>: vector<3xi32>}} {
19      // CHECK: %[[LB:.*]] = spv.constant 4 : i32
20      %lb = constant 4 : index
21      // CHECK: %[[UB:.*]] = spv.constant 42 : i32
22      %ub = constant 42 : index
23      // CHECK: %[[STEP:.*]] = spv.constant 2 : i32
24      %step = constant 2 : index
25      // CHECK:      spv.loop {
26      // CHECK-NEXT:   spv.Branch ^[[HEADER:.*]](%[[LB]] : i32)
27      // CHECK:      ^[[HEADER]](%[[INDVAR:.*]]: i32):
28      // CHECK:        %[[CMP:.*]] = spv.SLessThan %[[INDVAR]], %[[UB]] : i32
29      // CHECK:        spv.BranchConditional %[[CMP]], ^[[BODY:.*]], ^[[MERGE:.*]]
30      // CHECK:      ^[[BODY]]:
31      // CHECK:        %[[ZERO1:.*]] = spv.constant 0 : i32
32      // CHECK:        %[[OFFSET1:.*]] = spv.constant 0 : i32
33      // CHECK:        %[[STRIDE1:.*]] = spv.constant 1 : i32
34      // CHECK:        %[[UPDATE1:.*]] = spv.IMul %[[STRIDE1]], %[[INDVAR]] : i32
35      // CHECK:        %[[INDEX1:.*]] = spv.IAdd %[[OFFSET1]], %[[UPDATE1]] : i32
36      // CHECK:        spv.AccessChain {{%.*}}{{\[}}%[[ZERO1]], %[[INDEX1]]{{\]}}
37      // CHECK:        %[[ZERO2:.*]] = spv.constant 0 : i32
38      // CHECK:        %[[OFFSET2:.*]] = spv.constant 0 : i32
39      // CHECK:        %[[STRIDE2:.*]] = spv.constant 1 : i32
40      // CHECK:        %[[UPDATE2:.*]] = spv.IMul %[[STRIDE2]], %[[INDVAR]] : i32
41      // CHECK:        %[[INDEX2:.*]] = spv.IAdd %[[OFFSET2]], %[[UPDATE2]] : i32
42      // CHECK:        spv.AccessChain {{%.*}}[%[[ZERO2]], %[[INDEX2]]]
43      // CHECK:        %[[INCREMENT:.*]] = spv.IAdd %[[INDVAR]], %[[STEP]] : i32
44      // CHECK:        spv.Branch ^[[HEADER]](%[[INCREMENT]] : i32)
45      // CHECK:      ^[[MERGE]]
46      // CHECK:        spv.mlir.merge
47      // CHECK:      }
48      scf.for %arg4 = %lb to %ub step %step {
49        %1 = load %arg2[%arg4] : memref<10xf32>
50        store %1, %arg3[%arg4] : memref<10xf32>
51      }
52      gpu.return
53    }
54
55
56    // CHECK-LABEL: @loop_yield
57    gpu.func @loop_yield(%arg2 : memref<10xf32>, %arg3 : memref<10xf32>) kernel
58    attributes {spv.entry_point_abi = {local_size = dense<[16, 1, 1]>: vector<3xi32>}} {
59      // CHECK: %[[LB:.*]] = spv.constant 4 : i32
60      %lb = constant 4 : index
61      // CHECK: %[[UB:.*]] = spv.constant 42 : i32
62      %ub = constant 42 : index
63      // CHECK: %[[STEP:.*]] = spv.constant 2 : i32
64      %step = constant 2 : index
65      // CHECK: %[[INITVAR1:.*]] = spv.constant 0.000000e+00 : f32
66      %s0 = constant 0.0 : f32
67      // CHECK: %[[INITVAR2:.*]] = spv.constant 1.000000e+00 : f32
68      %s1 = constant 1.0 : f32
69      // CHECK: %[[VAR1:.*]] = spv.Variable : !spv.ptr<f32, Function>
70      // CHECK: %[[VAR2:.*]] = spv.Variable : !spv.ptr<f32, Function>
71      // CHECK: spv.loop {
72      // CHECK:   spv.Branch ^[[HEADER:.*]](%[[LB]], %[[INITVAR1]], %[[INITVAR2]] : i32, f32, f32)
73      // CHECK: ^[[HEADER]](%[[INDVAR:.*]]: i32, %[[CARRIED1:.*]]: f32, %[[CARRIED2:.*]]: f32):
74      // CHECK:   %[[CMP:.*]] = spv.SLessThan %[[INDVAR]], %[[UB]] : i32
75      // CHECK:   spv.BranchConditional %[[CMP]], ^[[BODY:.*]], ^[[MERGE:.*]]
76      // CHECK: ^[[BODY]]:
77      // CHECK:   %[[UPDATED:.*]] = spv.FAdd %[[CARRIED1]], %[[CARRIED1]] : f32
78      // CHECK-DAG:   %[[INCREMENT:.*]] = spv.IAdd %[[INDVAR]], %[[STEP]] : i32
79      // CHECK-DAG:   spv.Store "Function" %[[VAR1]], %[[UPDATED]] : f32
80      // CHECK-DAG:   spv.Store "Function" %[[VAR2]], %[[UPDATED]] : f32
81      // CHECK: spv.Branch ^[[HEADER]](%[[INCREMENT]], %[[UPDATED]], %[[UPDATED]] : i32, f32, f32)
82      // CHECK: ^[[MERGE]]:
83      // CHECK:   spv.mlir.merge
84      // CHECK: }
85      %result:2 = scf.for %i0 = %lb to %ub step %step iter_args(%si = %s0, %sj = %s1) -> (f32, f32) {
86        %sn = addf %si, %si : f32
87        scf.yield %sn, %sn : f32, f32
88      }
89      // CHECK-DAG: %[[OUT1:.*]] = spv.Load "Function" %[[VAR1]] : f32
90      // CHECK-DAG: %[[OUT2:.*]] = spv.Load "Function" %[[VAR2]] : f32
91      // CHECK: spv.Store "StorageBuffer" {{%.*}}, %[[OUT1]] : f32
92      // CHECK: spv.Store "StorageBuffer" {{%.*}}, %[[OUT2]] : f32
93      store %result#0, %arg3[%lb] : memref<10xf32>
94      store %result#1, %arg3[%ub] : memref<10xf32>
95      gpu.return
96    }
97  }
98}
99