1# ===========================================================================
2#         http://www.nongnu.org/autoconf-archive/ax_gcc_archflag.html
3# ===========================================================================
4#
5# SYNOPSIS
6#
7#   AX_GCC_ARCHFLAG([PORTABLE?], [ACTION-SUCCESS], [ACTION-FAILURE])
8#
9# DESCRIPTION
10#
11#   This macro tries to guess the "native" arch corresponding to the target
12#   architecture for use with gcc's -march=arch or -mtune=arch flags. If
13#   found, the cache variable $ax_cv_gcc_archflag is set to this flag and
14#   ACTION-SUCCESS is executed; otherwise $ax_cv_gcc_archflag is is set to
15#   "unknown" and ACTION-FAILURE is executed. The default ACTION-SUCCESS is
16#   to add $ax_cv_gcc_archflag to the end of $CFLAGS.
17#
18#   PORTABLE? should be either [yes] (default) or [no]. In the former case,
19#   the flag is set to -mtune (or equivalent) so that the architecture is
20#   only used for tuning, but the instruction set used is still portable. In
21#   the latter case, the flag is set to -march (or equivalent) so that
22#   architecture-specific instructions are enabled.
23#
24#   The user can specify --with-gcc-arch=<arch> in order to override the
25#   macro's choice of architecture, or --without-gcc-arch to disable this.
26#
27#   When cross-compiling, or if $CC is not gcc, then ACTION-FAILURE is
28#   called unless the user specified --with-gcc-arch manually.
29#
30#   Requires macros: AX_CHECK_COMPILER_FLAGS, AX_GCC_X86_CPUID
31#
32#   (The main emphasis here is on recent CPUs, on the principle that doing
33#   high-performance computing on old hardware is uncommon.)
34#
35# LICENSE
36#
37#   Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu>
38#   Copyright (c) 2008 Matteo Frigo
39#
40#   This program is free software: you can redistribute it and/or modify it
41#   under the terms of the GNU General Public License as published by the
42#   Free Software Foundation, either version 3 of the License, or (at your
43#   option) any later version.
44#
45#   This program is distributed in the hope that it will be useful, but
46#   WITHOUT ANY WARRANTY; without even the implied warranty of
47#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
48#   Public License for more details.
49#
50#   You should have received a copy of the GNU General Public License along
51#   with this program. If not, see <http://www.gnu.org/licenses/>.
52#
53#   As a special exception, the respective Autoconf Macro's copyright owner
54#   gives unlimited permission to copy, distribute and modify the configure
55#   scripts that are the output of Autoconf when processing the Macro. You
56#   need not follow the terms of the GNU General Public License when using
57#   or distributing such scripts, even though portions of the text of the
58#   Macro appear in them. The GNU General Public License (GPL) does govern
59#   all other use of the material that constitutes the Autoconf Macro.
60#
61#   This special exception to the GPL applies to versions of the Autoconf
62#   Macro released by the Autoconf Archive. When you make and distribute a
63#   modified version of the Autoconf Macro, you may extend this special
64#   exception to the GPL to apply to your modified version as well.
65
66AC_DEFUN([AX_GCC_ARCHFLAG],
67[AC_REQUIRE([AC_PROG_CC])
68AC_REQUIRE([AC_CANONICAL_HOST])
69
70AC_ARG_WITH(gcc-arch, [AC_HELP_STRING([--with-gcc-arch=<arch>], [use architecture <arch> for gcc -march/-mtune, instead of guessing])],
71	ax_gcc_arch=$withval, ax_gcc_arch=yes)
72
73AC_MSG_CHECKING([for gcc architecture flag])
74AC_MSG_RESULT([])
75AC_CACHE_VAL(ax_cv_gcc_archflag,
76[
77ax_cv_gcc_archflag="unknown"
78
79if test "$GCC" = yes; then
80
81if test "x$ax_gcc_arch" = xyes; then
82ax_gcc_arch=""
83if test "$cross_compiling" = no; then
84case $host_cpu in
85  i[[3456]]86*|x86_64*) # use cpuid codes, in part from x86info-1.7 by D. Jones
86     AX_GCC_X86_CPUID(0)
87     AX_GCC_X86_CPUID(1)
88     case $ax_cv_gcc_x86_cpuid_0 in
89       *:756e6547:*:*) # Intel
90          case $ax_cv_gcc_x86_cpuid_1 in
91	    *5[[48]]?:*:*:*) ax_gcc_arch="pentium-mmx pentium" ;;
92	    *5??:*:*:*) ax_gcc_arch=pentium ;;
93	    *6[[3456]]?:*:*:*) ax_gcc_arch="pentium2 pentiumpro" ;;
94	    *6a?:*[[01]]:*:*) ax_gcc_arch="pentium2 pentiumpro" ;;
95	    *6a?:*[[234]]:*:*) ax_gcc_arch="pentium3 pentiumpro" ;;
96	    *6[[9d]]?:*:*:*) ax_gcc_arch="pentium-m pentium3 pentiumpro" ;;
97	    *6[[78b]]?:*:*:*) ax_gcc_arch="pentium3 pentiumpro" ;;
98	    *6??:*:*:*) ax_gcc_arch=pentiumpro ;;
99            *f3[[347]]:*:*:*|*f4[1347]:*:*:*)
100		case $host_cpu in
101                  x86_64*) ax_gcc_arch="nocona pentium4 pentiumpro" ;;
102                  *) ax_gcc_arch="prescott pentium4 pentiumpro" ;;
103                esac ;;
104            *f??:*:*:*) ax_gcc_arch="pentium4 pentiumpro";;
105          esac ;;
106       *:68747541:*:*) # AMD
107          case $ax_cv_gcc_x86_cpuid_1 in
108	    *5[[67]]?:*:*:*) ax_gcc_arch=k6 ;;
109	    *5[[8d]]?:*:*:*) ax_gcc_arch="k6-2 k6" ;;
110	    *5[[9]]?:*:*:*) ax_gcc_arch="k6-3 k6" ;;
111	    *60?:*:*:*) ax_gcc_arch=k7 ;;
112	    *6[[12]]?:*:*:*) ax_gcc_arch="athlon k7" ;;
113	    *6[[34]]?:*:*:*) ax_gcc_arch="athlon-tbird k7" ;;
114	    *67?:*:*:*) ax_gcc_arch="athlon-4 athlon k7" ;;
115	    *6[[68a]]?:*:*:*)
116	       AX_GCC_X86_CPUID(0x80000006) # L2 cache size
117	       case $ax_cv_gcc_x86_cpuid_0x80000006 in
118                 *:*:*[[1-9a-f]]??????:*) # (L2 = ecx >> 16) >= 256
119			ax_gcc_arch="athlon-xp athlon-4 athlon k7" ;;
120                 *) ax_gcc_arch="athlon-4 athlon k7" ;;
121	       esac ;;
122	    *f[[4cef8b]]?:*:*:*) ax_gcc_arch="athlon64 k8" ;;
123	    *f5?:*:*:*) ax_gcc_arch="opteron k8" ;;
124	    *f7?:*:*:*) ax_gcc_arch="athlon-fx opteron k8" ;;
125	    *f??:*:*:*) ax_gcc_arch="k8" ;;
126          esac ;;
127	*:746e6543:*:*) # IDT
128	   case $ax_cv_gcc_x86_cpuid_1 in
129	     *54?:*:*:*) ax_gcc_arch=winchip-c6 ;;
130	     *58?:*:*:*) ax_gcc_arch=winchip2 ;;
131	     *6[[78]]?:*:*:*) ax_gcc_arch=c3 ;;
132	     *69?:*:*:*) ax_gcc_arch="c3-2 c3" ;;
133	   esac ;;
134     esac
135     if test x"$ax_gcc_arch" = x; then # fallback
136	case $host_cpu in
137	  i586*) ax_gcc_arch=pentium ;;
138	  i686*) ax_gcc_arch=pentiumpro ;;
139        esac
140     fi
141     ;;
142
143  sparc*)
144     AC_PATH_PROG([PRTDIAG], [prtdiag], [prtdiag], [$PATH:/usr/platform/`uname -i`/sbin/:/usr/platform/`uname -m`/sbin/])
145     cputype=`(((grep cpu /proc/cpuinfo | cut -d: -f2) ; ($PRTDIAG -v |grep -i sparc) ; grep -i cpu /var/run/dmesg.boot ) | head -n 1) 2> /dev/null`
146     cputype=`echo "$cputype" | tr -d ' -' |tr $as_cr_LETTERS $as_cr_letters`
147     case $cputype in
148         *ultrasparciv*) ax_gcc_arch="ultrasparc4 ultrasparc3 ultrasparc v9" ;;
149         *ultrasparciii*) ax_gcc_arch="ultrasparc3 ultrasparc v9" ;;
150         *ultrasparc*) ax_gcc_arch="ultrasparc v9" ;;
151         *supersparc*|*tms390z5[[05]]*) ax_gcc_arch="supersparc v8" ;;
152         *hypersparc*|*rt62[[056]]*) ax_gcc_arch="hypersparc v8" ;;
153         *cypress*) ax_gcc_arch=cypress ;;
154     esac ;;
155
156  alphaev5) ax_gcc_arch=ev5 ;;
157  alphaev56) ax_gcc_arch=ev56 ;;
158  alphapca56) ax_gcc_arch="pca56 ev56" ;;
159  alphapca57) ax_gcc_arch="pca57 pca56 ev56" ;;
160  alphaev6) ax_gcc_arch=ev6 ;;
161  alphaev67) ax_gcc_arch=ev67 ;;
162  alphaev68) ax_gcc_arch="ev68 ev67" ;;
163  alphaev69) ax_gcc_arch="ev69 ev68 ev67" ;;
164  alphaev7) ax_gcc_arch="ev7 ev69 ev68 ev67" ;;
165  alphaev79) ax_gcc_arch="ev79 ev7 ev69 ev68 ev67" ;;
166
167  powerpc*)
168     cputype=`((grep cpu /proc/cpuinfo | head -n 1 | cut -d: -f2 | cut -d, -f1 | sed 's/ //g') ; /usr/bin/machine ; /bin/machine; grep CPU /var/run/dmesg.boot | head -n 1 | cut -d" " -f2) 2> /dev/null`
169     cputype=`echo $cputype | sed -e 's/ppc//g;s/ *//g'`
170     case $cputype in
171       *750*) ax_gcc_arch="750 G3" ;;
172       *740[[0-9]]*) ax_gcc_arch="$cputype 7400 G4" ;;
173       *74[[4-5]][[0-9]]*) ax_gcc_arch="$cputype 7450 G4" ;;
174       *74[[0-9]][[0-9]]*) ax_gcc_arch="$cputype G4" ;;
175       *970*) ax_gcc_arch="970 G5 power4";;
176       *POWER4*|*power4*|*gq*) ax_gcc_arch="power4 970";;
177       *POWER5*|*power5*|*gr*|*gs*) ax_gcc_arch="power5 power4 970";;
178       603ev|8240) ax_gcc_arch="$cputype 603e 603";;
179       *) ax_gcc_arch=$cputype ;;
180     esac
181     ax_gcc_arch="$ax_gcc_arch powerpc"
182     ;;
183esac
184fi # not cross-compiling
185fi # guess arch
186
187if test "x$ax_gcc_arch" != x -a "x$ax_gcc_arch" != xno; then
188for arch in $ax_gcc_arch; do
189  if test "x[]m4_default([$1],yes)" = xyes; then # if we require portable code
190    flags="-mtune=$arch"
191    # -mcpu=$arch and m$arch generate nonportable code on every arch except
192    # x86.  And some other arches (e.g. Alpha) don't accept -mtune.  Grrr.
193    case $host_cpu in i*86|x86_64*) flags="$flags -mcpu=$arch -m$arch";; esac
194  else
195    flags="-march=$arch -mcpu=$arch -m$arch"
196  fi
197  for flag in $flags; do
198    AX_CHECK_COMPILER_FLAGS($flag, [ax_cv_gcc_archflag=$flag; break])
199  done
200  test "x$ax_cv_gcc_archflag" = xunknown || break
201done
202fi
203
204fi # $GCC=yes
205])
206AC_MSG_CHECKING([for gcc architecture flag])
207AC_MSG_RESULT($ax_cv_gcc_archflag)
208if test "x$ax_cv_gcc_archflag" = xunknown; then
209  m4_default([$3],:)
210else
211  m4_default([$2], [CFLAGS="$CFLAGS $ax_cv_gcc_archflag"])
212fi
213])
214