1; RUN: opt %loadPolly -polly-scops -analyze < %s | FileCheck %s
2target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32:64-S128"
3
4; void foo(long n, long m, long o, double A[n][m][o]) {
5;
6;   for (long i = 0; i < n-3; i++)
7;     for (long j = 4; j < m; j++)
8;       for (long k = 0; k < o-7; k++)
9;         A[i+3][j-4][k+7] = 1.0;
10; }
11
12; CHECK:      Assumed Context:
13; CHECK-NEXT: [o, m, n] -> {  :  }
14;
15; CHECK:      p0: %o
16; CHECK-NEXT: p1: %m
17; CHECK-NEXT: p2: %n
18; CHECK-NOT:  p3
19;
20; CHECK:      Statements {
21; CHECK-NEXT:     Stmt_for_k
22; CHECK-NEXT:         Domain :=
23; CHECK-NEXT:             [o, m, n] -> { Stmt_for_k[i0, i1, i2] : 0 <= i0 <= -4 + n and 0 <= i1 <= -5 + m and 0 <= i2 <= -8 + o };
24; CHECK-NEXT:         Schedule :=
25; CHECK-NEXT:             [o, m, n] -> { Stmt_for_k[i0, i1, i2] -> [i0, i1, i2] };
26; CHECK-NEXT:         MustWriteAccess :=    [Reduction Type: NONE] [Scalar: 0]
27; CHECK-NEXT:             [o, m, n] -> { Stmt_for_k[i0, i1, i2] -> MemRef_A[3 + i0, i1, 7 + i2] };
28; CHECK-NEXT: }
29
30define void @foo(i64 %n, i64 %m, i64 %o, double* %A) {
31entry:
32  br label %for.i
33
34for.i:
35  %i = phi i64 [ 0, %entry ], [ %i.inc, %for.i.inc ]
36  br label %for.j
37
38for.j:
39  %j = phi i64 [ 4, %for.i ], [ %j.inc, %for.j.inc ]
40  br label %for.k
41
42for.k:
43  %k = phi i64 [ 0, %for.j ], [ %k.inc, %for.k.inc ]
44  %offset0 = add nsw i64 %i, 3
45  %subscript0 = mul i64 %offset0, %m
46  %offset1 = add nsw i64 %j, -4
47  %subscript1 = add i64 %offset1, %subscript0
48  %subscript2 = mul i64 %subscript1, %o
49  %offset2 = add nsw i64 %k, 7
50  %subscript = add i64 %subscript2, %offset2
51  %idx = getelementptr inbounds double, double* %A, i64 %subscript
52  store double 1.0, double* %idx
53  br label %for.k.inc
54
55for.k.inc:
56  %k.inc = add nsw i64 %k, 1
57  %osub = sub nsw i64 %o, 7
58  %k.exitcond = icmp eq i64 %k.inc, %osub
59  br i1 %k.exitcond, label %for.j.inc, label %for.k
60
61for.j.inc:
62  %j.inc = add nsw i64 %j, 1
63  %j.exitcond = icmp eq i64 %j.inc, %m
64  br i1 %j.exitcond, label %for.i.inc, label %for.j
65
66for.i.inc:
67  %i.inc = add nsw i64 %i, 1
68  %nsub = sub nsw i64 %n, 3
69  %i.exitcond = icmp eq i64 %i.inc, %nsub
70  br i1 %i.exitcond, label %end, label %for.i
71
72end:
73  ret void
74}
75