1@rem
2@rem Searches for python.exe and may download a private copy from nuget.
3@rem
4@rem This file is supposed to modify the state of the caller (specifically
5@rem the MSBUILD variable), so we do not use setlocal or echo, and avoid
6@rem changing any other persistent state.
7@rem
8
9@rem No arguments provided means do full search
10@if '%1' EQU '' goto :begin_search
11
12@rem One argument may be the full path. Use a goto so we don't try to
13@rem parse the next if statement - incorrect quoting in the multi-arg
14@rem case can cause us to break immediately.
15@if '%2' EQU '' goto :one_arg
16
17@rem Entire command line may represent the full path if quoting failed.
18@if exist "%*" (set PYTHON="%*") & (set _Py_Python_Source=from environment) & goto :found
19@goto :begin_search
20
21:one_arg
22@if exist "%~1" (set PYTHON="%~1") & (set _Py_Python_Source=from environment) & goto :found
23
24:begin_search
25@set PYTHON=
26
27@rem If there is an active virtual env, use that one
28@if NOT "%VIRTUAL_ENV%"=="" (set PYTHON="%VIRTUAL_ENV%\Scripts\python.exe") & (set _Py_Python_Source=found in virtual env) & goto :found
29
30@set _Py_EXTERNALS_DIR=%EXTERNALS_DIR%
31@if "%_Py_EXTERNALS_DIR%"=="" (set _Py_EXTERNALS_DIR=%~dp0\..\externals)
32
33@rem If we have Python in externals, use that one
34@if exist "%_Py_EXTERNALS_DIR%\pythonx86\tools\python.exe" (set PYTHON="%_Py_EXTERNALS_DIR%\pythonx86\tools\python.exe") & (set _Py_Python_Source=found in externals directory) & goto :found
35
36@rem If HOST_PYTHON is recent enough, use that
37@if NOT "%HOST_PYTHON%"=="" @%HOST_PYTHON% -Ec "import sys; assert sys.version_info[:2] >= (3, 6)" >nul 2>nul && (set PYTHON="%HOST_PYTHON%") && (set _Py_Python_Source=found as HOST_PYTHON) && goto :found
38
39@rem If py.exe finds a recent enough version, use that one
40@for %%p in (3.8 3.7 3.6) do @py -%%p -EV >nul 2>&1 && (set PYTHON=py -%%p) && (set _Py_Python_Source=found %%p with py.exe) && goto :found
41
42@if NOT exist "%_Py_EXTERNALS_DIR%" mkdir "%_Py_EXTERNALS_DIR%"
43@set _Py_NUGET=%NUGET%
44@set _Py_NUGET_URL=%NUGET_URL%
45@set _Py_HOST_PYTHON=%HOST_PYTHON%
46@if "%_Py_HOST_PYTHON%"=="" set _Py_HOST_PYTHON=py
47@if "%_Py_NUGET%"=="" (set _Py_NUGET=%_Py_EXTERNALS_DIR%\nuget.exe)
48@if "%_Py_NUGET_URL%"=="" (set _Py_NUGET_URL=https://aka.ms/nugetclidl)
49@if NOT exist "%_Py_NUGET%" (
50    @echo Downloading nuget...
51    @rem NB: Must use single quotes around NUGET here, NOT double!
52    @rem Otherwise, a space in the path would break things
53    @rem If it fails, retry with any available copy of Python
54    @powershell.exe -Command Invoke-WebRequest %_Py_NUGET_URL% -OutFile '%_Py_NUGET%'
55    @if errorlevel 1 (
56        @%_Py_HOST_PYTHON% -E "%~dp0\urlretrieve.py" "%_Py_NUGET_URL%" "%_Py_NUGET%"
57    )
58)
59@echo Installing Python via nuget...
60@"%_Py_NUGET%" install pythonx86 -ExcludeVersion -OutputDirectory "%_Py_EXTERNALS_DIR%"
61@rem Quote it here; it's not quoted later because "py -x.y" wouldn't work
62@if not errorlevel 1 (set PYTHON="%_Py_EXTERNALS_DIR%\pythonx86\tools\python.exe") & (set _Py_Python_Source=found on nuget.org) & goto :found
63
64
65@set _Py_Python_Source=
66@set _Py_EXTERNALS_DIR=
67@set _Py_NUGET=
68@set _Py_NUGET_URL=
69@set _Py_HOST_PYTHON=
70@exit /b 1
71
72:found
73@echo Using %PYTHON% (%_Py_Python_Source%)
74@set _Py_Python_Source=
75@set _Py_EXTERNALS_DIR=
76@set _Py_NUGET=
77@set _Py_NUGET_URL=
78@set _Py_HOST_PYTHON=
79