1# ################################################################
2# Copyright (c) 2016-present, Yann Collet, Facebook, Inc.
3# All rights reserved.
4#
5# This source code is licensed under both the BSD-style license (found in the
6# LICENSE file in the root directory of this source tree) and the GPLv2 (found
7# in the COPYING file in the root directory of this source tree).
8# ################################################################
9
10cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
11
12# As of 2018-12-26 ZSTD has been validated to build with cmake version 3.13.2 new policies.
13# Set and use the newest cmake policies that are validated to work
14set(ZSTD_MAX_VALIDATED_CMAKE_MAJOR_VERSION "3")
15set(ZSTD_MAX_VALIDATED_CMAKE_MINOR_VERSION "13") #Policies never changed at PATCH level
16if("${CMAKE_MAJOR_VERSION}" LESS 3)
17  set(ZSTD_CMAKE_POLICY_VERSION "${CMAKE_VERSION}")
18elseif( "${ZSTD_MAX_VALIDATED_CMAKE_MAJOR_VERSION}" EQUAL "${CMAKE_MAJOR_VERSION}" AND
19        "${ZSTD_MAX_VALIDATED_CMAKE_MINOR_VERSION}" GREATER "${CMAKE_MINOR_VERSION}")
20    set(ZSTD_CMAKE_POLICY_VERSION "${CMAKE_VERSION}")
21else()
22    set(ZSTD_CMAKE_POLICY_VERSION "${ZSTD_MAX_VALIDATED_CMAKE_MAJOR_VERSION}.${ZSTD_MAX_VALIDATED_CMAKE_MINOR_VERSION}.0")
23endif()
24cmake_policy(VERSION ${ZSTD_CMAKE_POLICY_VERSION})
25
26set(CMAKE_BUILD_WITH_INSTALL_RPATH on)
27
28list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules")
29set(ZSTD_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../..")
30set(LIBRARY_DIR ${ZSTD_SOURCE_DIR}/lib)
31# Parse version
32include(GetZstdLibraryVersion)
33GetZstdLibraryVersion(${LIBRARY_DIR}/zstd.h zstd_VERSION_MAJOR zstd_VERSION_MINOR zstd_VERSION_PATCH)
34
35if( CMAKE_MAJOR_VERSION LESS 3 )
36  ## Provide cmake 3+ behavior for older versions of cmake
37  project(zstd)
38  set(PROJECT_VERSION_MAJOR ${zstd_VERSION_MAJOR})
39  set(PROJECT_VERSION_MINOR ${zstd_VERSION_MINOR})
40  set(PROJECT_VERSION_PATCH ${zstd_VERSION_PATCH})
41  set(PROJECT_VERSION "${zstd_VERSION_MAJOR}.${zstd_VERSION_MINOR}.${zstd_VERSION_PATCH}")
42  enable_language(C)   # Main library is in C
43  enable_language(CXX) # Testing contributed code also utilizes CXX
44else()
45  project(zstd
46    VERSION "${zstd_VERSION_MAJOR}.${zstd_VERSION_MINOR}.${zstd_VERSION_PATCH}"
47    LANGUAGES C   # Main library is in C
48              CXX # Testing contributed code also utilizes CXX
49    )
50endif()
51message(STATUS "ZSTD VERSION: ${zstd_VERSION}")
52set(zstd_HOMEPAGE_URL "http://www.zstd.net")
53set(zstd_DESCRIPTION  "Zstandard is a real-time compression algorithm, providing high compression ratios.")
54
55# Set a default build type if none was specified
56if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
57  message(STATUS "Setting build type to 'Release' as none was specified.")
58  set(CMAKE_BUILD_TYPE Release CACHE STRING "Choose the type of build." FORCE)
59  # Set the possible values of build type for cmake-gui
60  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
61endif()
62
63include(GNUInstallDirs)
64
65#-----------------------------------------------------------------------------
66# Add extra compilation flags
67#-----------------------------------------------------------------------------
68include(AddZstdCompilationFlags)
69ADD_ZSTD_COMPILATION_FLAGS()
70
71# Always hide XXHash symbols
72add_definitions(-DXXH_NAMESPACE=ZSTD_)
73
74#-----------------------------------------------------------------------------
75# Installation variables
76#-----------------------------------------------------------------------------
77message(STATUS "CMAKE_INSTALL_PREFIX: ${CMAKE_INSTALL_PREFIX}")
78message(STATUS "CMAKE_INSTALL_LIBDIR: ${CMAKE_INSTALL_LIBDIR}")
79
80#-----------------------------------------------------------------------------
81# Options
82#-----------------------------------------------------------------------------
83
84# Legacy support
85option(ZSTD_LEGACY_SUPPORT "LEGACY SUPPORT" OFF)
86
87if (ZSTD_LEGACY_SUPPORT)
88    message(STATUS "ZSTD_LEGACY_SUPPORT defined!")
89    add_definitions(-DZSTD_LEGACY_SUPPORT=5)
90else ()
91    message(STATUS "ZSTD_LEGACY_SUPPORT not defined!")
92    add_definitions(-DZSTD_LEGACY_SUPPORT=0)
93endif ()
94
95# Multi-threading support
96option(ZSTD_MULTITHREAD_SUPPORT "MULTITHREADING SUPPORT" ON)
97
98if (ZSTD_MULTITHREAD_SUPPORT)
99    message(STATUS "ZSTD_MULTITHREAD_SUPPORT is enabled")
100else ()
101    message(STATUS "ZSTD_MULTITHREAD_SUPPORT is disabled")
102endif ()
103
104option(ZSTD_BUILD_PROGRAMS "BUILD PROGRAMS" ON)
105option(ZSTD_BUILD_CONTRIB "BUILD CONTRIB" OFF)
106
107# Respect the conventional CMake option for enabling tests if it was specified on the first configure
108if (BUILD_TESTING)
109    set(ZSTD_BUILD_TESTS_default ON)
110else()
111    set(ZSTD_BUILD_TESTS_default OFF)
112endif()
113option(ZSTD_BUILD_TESTS "BUILD TESTS" ${ZSTD_BUILD_TESTS_default})
114if (MSVC)
115    option(ZSTD_USE_STATIC_RUNTIME "LINK TO STATIC RUN-TIME LIBRARIES" OFF)
116endif ()
117
118#-----------------------------------------------------------------------------
119# External dependencies
120#-----------------------------------------------------------------------------
121if (ZSTD_MULTITHREAD_SUPPORT AND UNIX)
122    set(THREADS_PREFER_PTHREAD_FLAG ON)
123    find_package(Threads REQUIRED)
124    if(CMAKE_USE_PTHREADS_INIT)
125        set(THREADS_LIBS "${CMAKE_THREAD_LIBS_INIT}")
126    else()
127        message(SEND_ERROR "ZSTD currently does not support thread libraries other than pthreads")
128    endif()
129endif ()
130
131#-----------------------------------------------------------------------------
132# Add source directories
133#-----------------------------------------------------------------------------
134add_subdirectory(lib)
135
136option(ZSTD_PROGRAMS_LINK_SHARED "PROGRAMS LINK SHARED" OFF)
137
138if (ZSTD_BUILD_PROGRAMS)
139    if (NOT ZSTD_BUILD_STATIC AND NOT ZSTD_PROGRAMS_LINK_SHARED)
140        message(SEND_ERROR "You need to build static library to build zstd CLI")
141    elseif(NOT ZSTD_BUILD_SHARED AND ZSTD_PROGRAMS_LINK_SHARED)
142        message(SEND_ERROR "You need to build shared library to build zstd CLI")
143    endif ()
144
145    add_subdirectory(programs)
146endif ()
147
148if (ZSTD_BUILD_TESTS)
149    enable_testing()
150    if (NOT ZSTD_BUILD_STATIC)
151        message(SEND_ERROR "You need to build static library to build tests")
152    endif ()
153
154    add_subdirectory(tests)
155endif ()
156
157if (ZSTD_BUILD_CONTRIB)
158    add_subdirectory(contrib)
159endif ()
160
161#-----------------------------------------------------------------------------
162# Add clean-all target
163#-----------------------------------------------------------------------------
164add_custom_target(clean-all
165   COMMAND ${CMAKE_BUILD_TOOL} clean
166   COMMAND rm -rf ${CMAKE_BINARY_DIR}/
167)
168
169#-----------------------------------------------------------------------------
170# Generate Package Config files
171#
172# This section is based on the boiler plate code from:
173# https://cmake.org/cmake/help/latest/manual/cmake-packages.7.html#creating-packages
174#-----------------------------------------------------------------------------
175include(CMakePackageConfigHelpers)
176write_basic_package_version_file(
177    "${CMAKE_CURRENT_BINARY_DIR}/zstdConfigVersion.cmake"
178    VERSION ${zstd_VERSION}
179    COMPATIBILITY SameMajorVersion
180    )
181
182# A Package Config file that works from the build directory
183export(EXPORT zstdExports
184    FILE "${CMAKE_CURRENT_BINARY_DIR}/zstdTargets.cmake"
185    NAMESPACE zstd::
186    )
187configure_file(zstdConfig.cmake
188    "${CMAKE_CURRENT_BINARY_DIR}/zstdConfig.cmake"
189    COPYONLY
190    )
191
192# A Package Config file that works from the installation directory
193set(ConfigPackageLocation ${CMAKE_INSTALL_LIBDIR}/cmake/zstd)
194install(EXPORT zstdExports
195    FILE zstdTargets.cmake
196    NAMESPACE zstd::
197    DESTINATION ${ConfigPackageLocation}
198    )
199install(FILES
200    zstdConfig.cmake
201    "${CMAKE_CURRENT_BINARY_DIR}/zstdConfigVersion.cmake"
202    DESTINATION ${ConfigPackageLocation}
203    )
204