1/*
2 * Copyright 2012, Google Inc.
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions are
7 * met:
8 *
9 *     * Redistributions of source code must retain the above copyright
10 * notice, this list of conditions and the following disclaimer.
11 *     * Redistributions in binary form must reproduce the above
12 * copyright notice, this list of conditions and the following disclaimer
13 * in the documentation and/or other materials provided with the
14 * distribution.
15 *     * Neither the name of Google Inc. nor the names of its
16 * contributors may be used to endorse or promote products derived from
17 * this software without specific prior written permission.
18 *
19 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
20 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
21 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
22 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
23 * OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
24 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
25 * LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
26 * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
27 * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
28 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
29 * OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
30 */
31
32apply plugin: 'idea'
33
34version = '2.0.3'
35
36def jarVersion = version
37
38if (!('release' in gradle.startParameter.taskNames)) {
39    def versionSuffix
40    try {
41        def git = org.eclipse.jgit.api.Git.open(file('.'))
42        def head = git.getRepository().getRef("HEAD")
43        versionSuffix = head.getObjectId().abbreviate(8).name()
44
45        if (!git.status().call().clean) {
46            versionSuffix += '-dirty'
47        }
48    } catch (Exception) {
49        // In case we can't get the commit for some reason,
50        // just use -dev
51        versionSuffix = 'dev'
52    }
53
54    def baseVersion = version
55    version = baseVersion + '-' + versionSuffix
56
57    // use something like module-1.2.3-dev.jar for the jar name, rather than the full
58    // module-1.2.3-001afe02-dirty.jar
59    jarVersion = baseVersion + '-dev'
60}
61
62// Note: please don't use this. This is strictly for the official releases
63// that are posted on, e.g. the bitbucket download page.
64task release() {
65}
66
67subprojects {
68    apply plugin: 'java'
69    apply plugin: 'idea'
70    apply plugin: 'maven'
71    apply plugin: 'signing'
72
73    group = 'org.smali'
74    version = parent.version
75
76    ext {
77        depends = [guava: 'com.google.guava:guava:14.0',
78                   findbugs: 'com.google.code.findbugs:jsr305:1.3.9',
79                   junit: 'junit:junit:4.6',
80                   antlr_runtime: 'org.antlr:antlr-runtime:3.5',
81                   antlr: 'org.antlr:antlr:3.5',
82                   commons_cli: 'commons-cli:commons-cli:1.2',
83                   jflex: 'de.jflex:jflex:1.4.3',
84                   proguard: 'net.sf.proguard:proguard-base:4.8'
85         ]
86    }
87
88    jar {
89        version = jarVersion
90    }
91
92    repositories {
93        mavenCentral()
94    }
95
96    signing {
97        required { gradle.taskGraph.hasTask("uploadArchives") }
98        sign configurations.archives
99    }
100
101    uploadArchives {
102        repositories.mavenDeployer {
103            configuration = configurations.archives
104
105            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
106
107            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
108                authentication(userName: sonatypeUsername, password: sonatypePassword)
109            }
110
111            pom.artifactId = project.name
112
113            pom.project {
114                name project.name
115                url 'http://smali.org'
116                packaging 'jar'
117                licenses {
118                    license {
119                        name 'The BSD 3-Clause License'
120                        url 'http://opensource.org/licenses/BSD-3-Clause'
121                        distribution 'repo'
122                    }
123                }
124                scm {
125                    connection 'scm:git:git://github.com/JesusFreke/smali.git'
126                    developerConnection 'scm:git:git@github.com:JesusFreke/smali.git'
127                }
128                developers {
129                    developer {
130                        id 'jesusfreke'
131                        name 'Ben Gruver'
132                        email 'jesusfreke@jesusfreke.com'
133                    }
134                }
135            }
136        }
137    }
138
139    tasks.getByPath(':release').dependsOn(uploadArchives)
140}
141
142buildscript {
143    repositories {
144        mavenCentral()
145    }
146    dependencies {
147        classpath 'org.eclipse.jgit:org.eclipse.jgit:2.0.0.201206130900-r'
148    }
149}
150
151task wrapper(type: Wrapper) {
152    gradleVersion = '1.8'
153}